VB.NETを咥えてWindows.Formsをつつく5－継承2。継承の甘い罠にご注意♪

前回の続きピヨッ。それにしてもボクは納得できないピヨ。だってぇ、ボクその様に設計して正しく実装したピヨ。
ドリィちゃん「それを言われると・・・説明し辛いわねぇ。貴方が微妙なもの作るからεπιστημηさんも中の人も困っていたじゃない。こういった間違いは現場でも起こるんだけど一番厄介ねぇ・・・」
ちゃんと動いているんだからいいじゃん♪ボクこの逃走ボタンをバージョンアップして、次はキー入力も受け付けないようにしようと思っているんだ♪今のままだとキー入力で押下されるからね♪
ドリィちゃん「どういったらいいんだろう・・・そうだ！実装する際に使う場面考えた？どういう局面で逃走ボタンは使うの？」
えっ？・・・・・いやぁ、面白いと思って、コンパイルしたらちゃんと動いていたから・・・えっと、使う場面は後で考えるピヨォ・・・
ドリィちゃん「それは継承の甘い罠❤に嵌っているわ。確かに継承は便利な機能で、覚えたての頃は誰でも使いたくなるけど、もともとプログラム言語は何のためにあるのかしら？」
それは・・・誰かの仕事を助けて社会の役に立つためピヨ。
ドリィちゃん「？！貴方の口からそんな真面目な答えが帰ってくるとは思わなかった。ちょっと驚いたたわ。それはさて置き。その答えは正解よ。という事は、目的があって使うものよね？」
あっそうか！ボクはプログラムやコンパイラの機能だけを考えて作ったから、手段が目的になっていたんだね。
ドリィちゃん「そうよ。わかればよろしい❤遊びの時はいいんだけど、その調子で設計を考えたらプロジェクトは破綻するわよ。だから、プログラミングを学ぶ時は文法を機械的に覚えたり、使いたい機能を設計に反映したりせず、常に目的を意識して機能を選択しないと駄目よ。とくに継承は生産性が高いから、逆に広い意味でのバグも効率的に生産できてしまうわけよ。」
わかったよドリィちゃん。継承の文法じゃなくて、実務を意識した使い方を追求していくピヨ♪
ドリィちゃん「じゃあね、今回は特別に継承の整合性を判断するための項目を教えてあげる❤」


【5つの継承チェック項目】

1. 継承の元となるクラスと、そのクラスの定義を継承するクラスの目的は一致していますか？
2. コードの行数だけで「面倒だから派生しよう」と脊髄反応的に継承の機能を使っていませんか？現在は同じコードが多くとも、クラスの定義が違えば共通するコードは将来減ります。
3. 意味的に正しい継承関係ですか？多くの人が納得できる継承関係じゃないとコードの保守性が下がります。
4. そのクラスが持つメソッドは本当に同じ意味ですか？継承の元となるクラスとこれから作ろうとしているクラスのメソッドは同じ意味ですか？メソッドは動詞で命名する事が多いので、偶然同じ名前になっていることがあります。その様な場合はインターフェースを検討するのがいいでしょう。
5. そのクラスの使うべき局面を詳細に説明できますか？

ドリィちゃん「大まかなチェックはこれでいいと思うわ。この5つの項目をパスできない場合継承以外の手段も検討してね❤コツはコードベースで物事を考えないで、現実的に考える事よぉ。あと、クラスの階層はあまり深いと駄目よ！普通は2，3を目安にしてね。」
う～～～ん。ドリィちゃんボクこれじゃあ分からないよ。コードもないしね・・・ボク具体例がないと分からないピヨォ。
ドリィちゃん「そっか。仕方ないわね。次回以降サンプルコードを交えて具体的に説明するわ。」
わーい♪そうこなくっちゃ♪
ドリィちゃん「次回へ続く。」

VB.NETを咥えてWindows.Formsをつつく4－継承1。親の仕様を無視するな！逃走ボタン。

前回はオブジェクト指向の目玉である継承をつついたピヨ♪だけどまだつつきたりないから今回も継承をつつくピヨ♪ということで、早速サンプルコードをご覧あれ！

Imports System
Imports System.Text
Imports System.Drawing
Imports System.Windows.Forms

Public Class FormProgram
    Public Shared Sub Main()
        Dim frm As PiyoForm = Nothing
        For i As Integer = 0 To 100
            'ピヨフォームを用意するピヨ♪
            frm = New PiyoForm(i)
            frm.Show()
            '逃げるボタンを追加♪
            Dim btn As EscapingButton = New EscapingButton()
            frm.Controls.Add(btn)
        Next
        frm.BackColor = Color.Red
        Application.Run(frm)
    End Sub
End Class


Imports System.Drawing
Imports System.Windows.Forms

'逃走ボタン
Public Class EscapingButton
    Inherits Button

    Private rand As Random

    Sub New()
        rand = New Random()
        Me.Text = "私をクリックしないで！"
        Me.Width = Me.CreateGraphics().MeasureString(Me.Text &  _ 
                           "あ", Me.Font).ToSize().Width
    End Sub

    Protected Overrides Sub OnClick(ByVal e As System.EventArgs)
        MyBase.OnClick(e)
        'クリックされたら消える
        MessageBox.Show("ぐはあっ！やられた・・・")
        Me.Dispose()
    End Sub

    Protected Overrides Sub OnMouseHover(ByVal e As System.EventArgs)
        MyBase.OnMouseHover(e)

        'クリックされないように逃げる
        Dim x As Integer = rand.Next(0, Me.Width + 100)
        Dim y As Integer = rand.Next(0, Me.Height + 100)
        Me.Location = New Point(x, y)

        '画面上をはみ出た場合戻る
        If Not Me.Parent Is Nothing Then
            Dim flag As Boolean = False
            If x >= Me.Parent.Width Then
                x = rand.Next(0, Me.Parent.Width)
                flag = True
            End If
            If y >= Me.Parent.Height Then
                y = rand.Next(0, Me.Parent.Height)
                flag = True
            End If
            If flag = True Then
                Me.Location = New Point(x, y)
            End If
        End If

    End Sub

End Class

こんな具合に継承を禁止されていないクラスは何でも継承できるピヨ。じゃあ、このサンプルコードを動かそう！あっ！丁度いい時に人が来た。ドリィちゃんちょっとこれ見て♪
ドリィちゃん「何この悪趣味な画面？！それに何かしらこのボタン・・・そんなこと言われたらクリックしたくなるじゃないのぉ。えぃ！あっ逃げられたぁ！こしゃくなぁぁーえぃっ！えいっ！えいっ！よしやったわよ！あれ？何でボタンなのにクリックしたら消えるの？」
ボクオリジナルの逃走ボタンだからさ♪
ドリィちゃん「？？？あのねぇ。ボタンはクリックされるためにあるんだから、このボタン意味ないわよ！」
が～ん！
ドリィちゃん「ばかぁ。もうまた変なものつくてぇ。まぁ、面白いけどね（ぼそ）論理的整合性をコンパイラはチェックしてくれないから、みんな注意してね❤親クラスの仕様をじっくり調べて、注意して子クラスを実装してね❤」
今回の教訓：子クラスを実装する時、親クラスの役割をよく考えて論理的整合性が崩れないようにしよう。
※適切な表現にするために記事を修正しました。

VB.NETを咥えてWindows.Formsをつつく3－継承。ピヨ伝染♪

前回はインスタンスと型を堪能したピヨ。今度は継承をつつこう♪オブジェクト指向といえば、やっぱり継承が使えなきゃ面白くないよね。
前回のプログラムでボクはどうしても気になる事があったんだ。それはフォームのキャプションに「ピヨ」数が多くなったら時全部見えなかったことピヨォ。そんなの嫌だからボクは全部見えるように新しいフォームを作成する事を決心したピヨッ！という事で新しいPiyoFormをご覧あれ！

Imports System
Imports System.Text
Imports System.Drawing
Imports System.Windows.Forms

Public Class PiyoForm
    Inherits Form 'Formを継承して新しいクラスを作る♪

    Sub New(ByVal count As Integer)
        Dim str As StringBuilder = New StringBuilder(count * 2)
        For i As Integer = 0 To count
            str.Append("ピヨ")
        Next
        Me.Text = str.ToString()
    End Sub

    Protected Overrides Sub OnResize(ByVal e As System.EventArgs)
        Invalidate()
    End Sub

    Protected Overrides Sub OnPaint(ByVal e As PaintEventArgs)
        MyBase.OnPaint(e)

        '線画処理の準備
        Dim grfx As Graphics = e.Graphics
        Dim rang As RectangleF =  _ 
              New RectangleF(0, 0, ClientSize.Width, ClientSize.Height)

        '声を大にして言いたい
        Dim font As Font = _ 
              New Font(Me.Font.FontFamily, Me.Font.Size + 2, FontStyle.Bold)

        '思いっきりピヨと叫ぶ！
        grfx.DrawString(Me.Text, font, Brushes.Black, rang)
    End Sub

End Class

Public Class FormProgram
    Public Shared Sub Main()
        Dim frm As PiyoForm = Nothing
        For i As Integer = 0 To 100
            frm = New PiyoForm(i)  '作りやすい
            frm.Show()
        Next
        frm.BackColor = Color.Red
        Application.Run(frm)
    End Sub
End Class

このサンプルプログラムを実行して♪今度の新しいクラスは無事ピヨが全部見えるピヨ♪♪しかも作り方も簡単になったしね。この様にして既存の型を拡張して新しい型を定義する事を継承とイメージすればいいピヨ。学術的に言うと不完全だけど慣れないうちは気にしない♪気にしない♪この例の様に、何度も同じコードを書く手間を省きたい時に使用したらいいと思う。えっ？PiyoFormを何度も使うのかって？もちろん使うピヨ。素敵なクラスだもんね♪
今回はこれでお終い。次回お楽しみに♪

VB.NETを咥えてWindows.Formsをつつく2－型とインスタンス。ラーメンちゃう。

前回はFormオブジェクトがオブジェクト指向を醸し出している所までつついたピヨ♪ということで、どこがオブジェクト指向なのかを今回囀ることにするピヨ。
オブジェクト指向といえば、先ず最初に型とインスタンスという用語を聞いた人が多いと思う。この概念がしっくりいかなくて困る人もいるらしいピヨ。インスタンスって言ってもインスタンスラーメンの事じゃないから注意してね。即席を意味するインスタンスちゃうよ。こっちと勘違いしてしまうと何のことやらわからなくなっちゃうよ。チャウチャウちゃうという事だね♪・・・
おっほん。それはさておき、前回の例でもインスタンスは出ていたピヨ。それがどこだか分かるかな？

Dim frm As Form = New Form()

この部分がインスタンスを生成している部分なんだ。でもこれだけじゃあ、あんまりインスタンスのイメージが湧かないよね？そんな時は・・・やっぱりプログラミング♪考え込まないで兎に角打つべし！打つべし！

Imports System
Imports System.Text
Imports System.Drawing 'System.Drawing.dllの参照を追加してね♪
Imports System.Windows.Forms

Public Class FormProgram
    Public Shared Sub Main()
        Dim frm As Form = Nothing
        Dim str As StringBuilder = New StringBuilder()
        For i As Integer = 0 To 100
            str.Append("ピヨ")
            frm = New Form()
            frm.Text = str.ToString()
            frm.Show()
        Next
        frm.BackColor = Color.Red
        Application.Run(frm)
    End Sub
End Class

このプログラムを実行してみよう♪わぉ！吃驚！101ピヨのピヨフォームが表示されるピヨッ♪これで、インスタンスのイメージがつかめたかな？見ての通り、インスタンスとは何らかの形（型）から作ったものの事なんだ。先に断っておくけど、これは学問としての正式な定義ではないピヨ。でも、インスタンスのイメージがつかみ難い時は、このサンプルコードの実行画面を思い出そう。そうすれば何となくわかるよね？
あっそうそう肝心な事をまだ言っていなかったね。この大量のピヨフォームを素早く閉じたい場合は最後の赤いフォームを閉じよう。そうすれば全てのフォームが閉じられるピヨ。今回はこれでお終い♪次回をお楽しみに♪

VB.NETを咥えてWindows.Formsをつつく1－足りないものは愛（コード）♪

前回フォームの挙動が変で、足りないのは愛というところまで進んだピヨ♪気になって仕方が無い人も居るだろうから、その愛の形を早速お見せするピヨッ♪

Imports System
Imports System.Windows.Forms

Public Class FormProgram
    Public Shared Sub Main()
        Dim frm As Form = New Form()
        frm.Show()
        Application.Run(frm) 'ここに注目！
    End Sub
End Class

じゃーん。たった1行のコードを加えるだけで何時もの挙動のフォームが表示されたピヨ♪やったね♪最近の若い人はこの感動分かるかな？分からないだろうなー？ということで、この1行がどれ程の意味をこめているのか分かってもらうためにWin32でフォームを表示するプログラムをお見せするピヨ♪覚悟はいい？心臓が悪いVBプログラマは注意してね。

#include 

LRESULT CALLBACK WndProc( HWND hWnd, UINT uMsg, WPARAM wParam, LPARAM );

int WINAPI WinMain( HINSTANCE hInst, HINSTANCE hPrevInst,
                    LPSTR lpCmdLine, int nCmdShow)
{
    HWND hWnd;
    MSG msg;
    WNDCLASS form;
    static TCHAR appName[] = TEXT( "FormPiyo♪" );
    TCHAR title[] = TEXT( "画面ピヨ♪" );
    
    // ウィンドウ・クラスの登録
    ZeroMemory( &form, sizeof( form ) );
    form.lpfnWndProc = WndProc;
    form.hInstance = hInst;
    form.hIcon = LoadIcon( 0, IDI_APPLICATION);
    form.hCursor = LoadCursor( 0, IDC_ARROW);
    form.hbrBackground = (HBRUSH)COLOR_BACKGROUND;
    form.lpszClassName = appName;
    if( !RegisterClass( &form) ) return 0;
    
    // メイン・ウィンドウの作成
    hWnd = CreateWindow( 
                    appName, 
                    title,
                    WS_OVERLAPPEDWINDOW,
                    CW_USEDEFAULT, 
                    CW_USEDEFAULT,
                    CW_USEDEFAULT, 
                    CW_USEDEFAULT,
                    0,
                    0, 
                    hInst, 
                    NULL);
    ShowWindow( hWnd, nCmdShow);
    UpdateWindow( hWnd );
    
    // メッセージ・ループ
    while( GetMessage( &msg, 0, 0, 0) ){
        DispatchMessage( &msg);
    }
    return msg.wParam;
}

LRESULT CALLBACK WndProc( HWND hWnd, UINT uMsg, WPARAM wParam, LPARAM lParam)
{
    switch( uMsg){
    case WM_DESTROY:
        PostQuitMessage( 0 );
        return 0;
    }
    return DefWindowProc( hWnd, uMsg, wParam, lParam);
}

嗚呼、懐かしい。眩暈がしそうな量のコードだよね♪これを数行で実行できるなんてVB.NETは凄い生産だね。これもオブジェクト指向のお陰と言ってもいいとボクは思うピヨ♪ちなみに、このCのコードの方がいいと思ったVBプログラマが居たら今すぐC系言語をつつく事をお勧めするピヨ♪実はボクもこのCプログラムを見てときめいたからC系言語を楽習したんだ。
それはさておき、この生産性がオブジェクト指向のお陰といった理由は・・・次回へ続く♪

VB.NETを咥えてWindows.Formsをつつく0－兎に角フォームを出してみる！

ご要望に答えて、新しい連載を開始するピヨ♪この連載では、Windows.Formsを通じてオブジェクト指向を体感する事を目的としているピヨッ♪さあ、ボクと一緒にグラフィカルにオブジェクト指向を楽習しよう♪
初めは一番簡単なフォームを表示するところからやってみるピヨ。みんな、文章を読むだけじゃなくて触りたいよね？早速開発ソフトを立ち上げよう♪立ち上がったら殻、いや空のプロジェクトを作ってね♪えっ？何でWindowsフォームアプリケーションにしないのかって？それはねぇ、そんなことしたらコードの海で溺れるからだよ。いきなり開発ソフトが生成したコードを読んで分かるのならば、この連載読まないよね。分かってもらえたと思うから作業をすするめるピヨ。
次は参照の追加で、SystemとSystem.Windows.Formsを追加してね。それが終わったら、プロジェクトのアプリケーションの種類をコンソールに設定しよう。OK？何でコンソールなのか疑問に感じるだろうけど、ひとまずこうして欲しいな♪これで準備は終わりで、ついにお楽しみのサンプルコードを投下するピヨッ！とぉー


バサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサ

Imports System
Imports System.Windows.Forms

Public Class FormProgram
    Public Shared Sub Main()
        Dim frm As Form = New Form()
        frm.Show()
        Console.ReadLine()
    End Sub
End Class

早速動かしてみて♪みて♪コンソール画面と一緒にフォームが表示されるピョ♪・・・あれ？だけど、何だか様子が変だよね。フォームにカーソルを合わすとアイコンが時計になるし・・・そう、このプログラムはWindowsアプリとして何かが足りないんだ。その何かというとコードなんだピヨッ♪そのコードは・・・
いいところで次回へ続く♪お楽しみに♪