VB.NETをつつく22－イベント。そっちから言ってよね。

インドリとドリィちゃんが作った動物園基幹システムの働きもあったのか、わんくま動物園は大繁盛しました。 でも、ドリィちゃんはとっても悩んでいました。
インドリィちゃん「くまの中さんは何処へ行ったの？」
インドリ「大阪勉強会だよ。ボクもWebで参加したけどすごく楽しかったピヨッ。」
インドリィちゃん「大阪勉強会はもう終わったでしょ！。何時まで浮かれているのよぉ。まったく・・・ まあいいわ。犬のじゃんぬさんは何処へ行ったの？」
インドリ「うーんとねえ。仕事に疲れている様子だったから、息抜きにネタを求めてスイーツ（笑）を観察しに街へ出かけたと思うピヨ。」
インドリィちゃん「それ、ただの勘でしょぉ。もぅ。本当にインドリは頼りにならないわねぇぇ。」
そうなんです。わんくま動物園の個性的な面々は人気者なので、忙しい彼らが何処へ行ったのか全然把握できなかったのです。 これでは動物園は管理出来ません。鶏唐揚さんが危うくお客に食べられそうになったり、画伯がセクハラしたり、 シャノンさんが宇宙の真理を求めて行方不明になったり・・・etc とにかく色々なハプニングが起こりました。 それで困り果てたドリィちゃんは一つのアイデアを思いつきました。
インドリィちゃん「そうだわ。本人に自己申告してもらってそれに対処しよう。」
今度の例の場合のように、何かのオブジェクトを一部始終監視するには向いていない処理は、 イベントを使用します。生き物には自由に生きる権利があるからね。

※イメージとしてはButtonオブジェクトのClickが分かりやすいと思います。
※でもお話しを書かなきゃ面白くないからね♪

そこまで決まれば話しは早いです。さっそくドリィちゃんは報告する内容を実装しました。
みんなも一緒にみてみよう。

Public Class MoveEventArgs
    Inherits EventArgs 'ここに注目

    '移動先
    Private m_destination As String
    Public Property Destination() As String
        Get
            Return m_destination
        End Get
        Set(ByVal value As String)
            m_destination = value
        End Set
    End Property

    '移動目的
    Private m_purpose As String
    Public Property Purpose() As String
        Get
            Return m_purpose
        End Get
        Set(ByVal value As String)
            m_purpose = value
        End Set
    End Property

    Sub New(ByVal destination As String, ByVal purpose As String)
        Me.m_destination = destination
        Me.m_purpose = purpose
    End Sub
End Class

ひとまず、移動先と移動目的さえ分かれば何とかなるとドリィちゃんは考えたのです。 勿論このクラスを定義しただけでは何も起こりません。ですから引き続きドリィちゃんはAnimalクラスに変更を加えました。 こっちのコードも見てみよう。

注目するべきところだけ抜粋
Public MustInherit Class Animal

    'イベントの要素を定義    
    Public Event MoveEvent(ByVal sender As Object, ByVal e As MoveEventArgs)

    'イベントの発生を通知するメソッド    
    Protected Sub OnMove(ByVal e As MoveEventArgs)
        RaiseEvent MoveEvent(Me, e)
    End Sub

    '入力された値を正しいイベントに変換するメソッド 
    '※元からあるMoveメソッドを修正しました
    Public Overridable Sub Move( _ 
        ByVal destination As String, ByVal purpose As String)

        Dim e As MoveEventArgs = New MoveEventArgs(destination, purpose)
        OnMove(e)
    End Sub

End Class

※ここからはドリィちゃんが書いています。口が悪くなるから心して読んでね（インドリより）

ふぅ～。作業が終わったから私が説明するわ。一回しか言わないからちゃんと聞きなさい。
イベントを実装する手順は次の通り。

• 1．イベントで知りたい情報を定義する。
• 2．イベントの要素を定義する。
• 3．イベントの発生を通知するメソッドを定義する。
• 4．入力された値を正しいイベントに変換するメソッドを定義する。

それじゃ、個々の事項を説明するわ。

バサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサ

トリ邪魔。部屋の中で飛ぶな。
1の手順ではEventArgsから派生したクラスを定義。 いい、EventArgsよ。他のオブジェクトは駄目。我儘は許さないぃぃ。

バサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサ

（黙って窓を開ける）
2の手順では、Eventを宣言することになるわ。

アクセス修飾子 Event イベントの名前 メソッドの定義 

VB.NETは説明が簡単で良い。じゃあ、次。

バサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサ

だ・か・ら、室内で飛ばないでぇぇ！。羽がキーボードの上に落ちるでしょぉ。もぉ。
VB.NETは説明がやっぱり楽。RaiseEventでイベントを発行する。以上。 本当は内部で色々やっているけど説明が難しいわ。 これを理解するにはデリゲートを知らなければいけないから、 今のところは内部を気にしないで。 イベントに対応するメソッドを発動する。 と今のところ思っていて。これも後でインドリに説明させるから。
インドリ「ちょっと。ドリィちゃん。デリゲートの説明全てボクに任せるのかい？」
それが何か？
インドリ「・・・わかったよ。」
ということで細かいところは次回説明から最後へ行く。

バサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサバサ

逃げたか。でも大丈夫。時間ちゃんとデリゲート説明させるわ。
最後の手順はとても単純。1の手順で定義したEventArgsの派生クラスのインスタンスを作って、3の手順で定義したメソッドへ投げるだけ。 これで終わりといいたいところだけど、今回の例の場合派生クラスも変更する必要がある。 ということで私のコードを見なさい。

Public Class Bird

    Inherits Animal

    Public Sub New(ByVal name As String, ByVal age As Integer)
        MyBase.New(name, age)
    End Sub

    Public Overrides Sub Move( _ 
        ByVal destination As String, ByVal purpose As String)

        Console.WriteLine("バサバサ飛ぶ")
        MyBase.Move(destination, purpose)
    End Sub

End Class

'新しく追加
Public Class Bear
    Inherits Animal

    Public Sub New(ByVal name As String, ByVal age As Integer)
        MyBase.New(name, age)
    End Sub

    Public Overrides Sub Move( _ 
        ByVal destination As String, ByVal purpose As String)
        
        Console.WriteLine("のしのし歩く")
        MyBase.Move(destination, purpose)
    End Sub

End Class

Public Class Dog
    Inherits Animal

    Public Sub New(ByVal name As String, ByVal age As Integer)
        MyBase.New(name, age)
    End Sub

    Public Overrides Sub Move( _ 
        ByVal destination As String, ByVal purpose As String)

        Console.WriteLine("タッタ走る")
        MyBase.Move(destination, purpose)
    End Sub

End Class

MyBase.Moveとなっているところを注目しなさい。 これは親クラスのメソッドを呼び出しているの。 この文が無いとイベントが発動できないから絶対に付けなさい。 ここまで来たら後はそれを使うだけ。使っている様子を見なさい。そうすれば理解できるはずよ。

'変更した所だけ抜粋
Public Class Human

    Public Overrides Sub Move( _ 
        ByVal destination As String, ByVal purpose As String)

        Console.WriteLine("テクテク歩く")
        '人間は管理しないのでMyBaseを使わない
    End Sub

    Public Sub Management(ByRef target As Animal)
        'AddHandlerでイベントとこのクラスを関連付けている
        AddHandler target.MoveEvent, AddressOf Target_MoveEvent
    End Sub

    Private Sub Target_MoveEvent( _ 
        ByVal sender As Object, ByVal e As MoveEventArgs)

        Dim target As Animal = CType(sender, Animal)
        If target.Name = "インドリ" Then
            Console.WriteLine("{0}が逃亡するのを確認した。" & vbLf & _
                "行き先：{1}" & vbLf & "目的：{2}" & vbLf, _
                target.Name, e.Destination, e.Purpose)
        Else
            Console.WriteLine("「{0}さん」が移動するのを確認した。\n"  _ 
               & vbLf & "行き先：{1}" & vbLf & "目的：{2}" & vbLf, _
                target.Name, e.Destination, e.Purpose)
        End If
    End Sub
End Class

Public Class Module1

    Public Shared Sub Main()
        Dim dre As Human = New Human("ドリィちゃん", 16)
        dre.Talk()
        dre.Move("わんくま動物園", "事務仕事")
        Console.WriteLine("ドリィちゃんが事務仕事を始めます。")
        Console.WriteLine("")

        Dim tori As InDori = New InDori(29)
        dre.Management(tori)
        tori.Talk()
        tori.Move("じゃんぬねっと", "遊び")

        Dim naka As Bear = New Bear("中", 33)
        dre.Management(naka)
        naka.Talk()
        naka.Move("東京", "勉強会")

        Dim jyannnu As Dog = New Dog("じゃんぬ", 25)
        dre.Management(jyannnu)
        jyannnu.Talk()
        jyannnu.Move("街", "スイーツ（笑）観察")
    End Sub

End Class

何度かステップ実行して。そうすれば分かるはず。 私は気の聞いたこと言えないからこれでお終い。 そうそう。一つ言い忘れたわ。
これはネタだから実在する人物や団体とは一切関係ありません。
笑い流してね。